Gérer les exécuteurs avec Terraform

​

Avant de commencer

• Terraform et le fournisseur Terraform CoreWeave. Les exemples utilisent la version 0.26.0 ou ultérieure du fournisseur, dans la série 0.x.
• Un cluster CKS existant, son identifiant unique universel (UUID) et son Availability Zone. Ces valeurs figurent sur la page Clusters de la Cloud Console.
• Un jeton d’accès à l’API CoreWeave disposant de l’autorisation SANDBOX_ADMIN. Voir Gérer les jetons d’accès à l’API et Gérer les politiques d’accès.
• Un backend d’état Terraform doté de contrôles d’accès. Terraform peut stocker dans l’état les valeurs de remplacement de l’environnement de l’exécuteur ainsi que les valeurs de politique, même s’il les marque comme sensibles.

​

Configurer l’authentification

export COREWEAVE_API_TOKEN="$CW_API_KEY"

​

Définir l’exécuteur

terraform {
  required_providers {
    coreweave = {
      source  = "coreweave/coreweave"
      version = "~> 0.26"
    }
  }
}

provider "coreweave" {}

variable "runner_id" {
  type        = string
  description = "Runner identifier, unique within your organization."
}

variable "cluster_id" {
  type        = string
  description = "UUID of the existing CKS cluster."
}

variable "zone" {
  type        = string
  description = "Availability Zone of the existing CKS cluster."
}

resource "coreweave_sandbox_managed_runner" "runner" {
  runner_id  = var.runner_id
  cluster_id = var.cluster_id
  zone       = lower(var.zone)

  spec = {
    release_channel = "RELEASE_CHANNEL_STABLE"
    maintenance_policy = {
      windows = [{ cron = "0 2 * * SAT", duration_seconds = 3600 }]
    }
    overrides = {
      resources = {
        cpu_request    = "1"
        memory_request = "2Gi"
        cpu_limit      = "4"
        memory_limit   = "8Gi"
      }
    }
  }

  policy = {
    display_name = "Sandbox constraints"
    constraints = {
      resources = {
        default_cpu    = "1"
        default_memory = "2Gi"
        max_cpu        = "8"
        max_memory     = "32Gi"
        max_gpu_count  = 0
      }
      lifecycle = { default_lifetime_seconds = 3600 }
    }
  }
}

output "runner_status" {
  value = {
    runner_id           = coreweave_sandbox_managed_runner.runner.runner_id
    install_status      = coreweave_sandbox_managed_runner.runner.install_status
    connection_status   = coreweave_sandbox_managed_runner.runner.connection_status
    active_revision     = coreweave_sandbox_managed_runner.runner.active_revision
    target_revision     = coreweave_sandbox_managed_runner.runner.target_revision
    rollout_in_progress = coreweave_sandbox_managed_runner.runner.rollout_in_progress
  }
}

• spec configure l’exécuteur. Dans cet exemple, spec.overrides.resources dimensionne les Pods propres à l’exécuteur, et la fenêtre de maintenance commence le samedi à 2 h UTC.
• policy configure les bacs à sable desservis par l’exécuteur. Cet exemple plafonne le CPU et la mémoire de chaque conteneur de sandbox, interdit les GPU avec max_gpu_count = 0 et définit une durée de vie par défaut d’une heure. Cette durée de vie par défaut ne constitue pas une durée de vie maximale. Pour adapter les contraintes à vos charges de travail, consultez Configurer une politique de sandbox.

runner_id  = "[RUNNER-ID]"
cluster_id = "[CLUSTER-ID]"
zone       = "[ZONE]"

​

Appliquer et vérifier le déploiement

1. Initialisez le fournisseur et validez la configuration :
   terraform init
   terraform validate
   
2. Examinez et appliquez le plan :
   terraform plan -out=runner.tfplan
   terraform apply runner.tfplan
   
   Si l’application réussit, cela signifie que l’API a accepté la configuration. L’installation et le déploiement de l’exécuteur se poursuivent de manière asynchrone.
3. Actualisez le statut observé et examinez la sortie :
   terraform plan -refresh-only -out=runner-status.tfplan
   terraform apply runner-status.tfplan
   terraform output runner_status
   
   L’exécuteur est prêt lorsque install_status vaut RUNNER_INSTALL_STATUS_READY, que connection_status vaut RUNNER_CONNECTION_STATUS_CONNECTED et que active_revision est égal à target_revision. Si le provisionnement est toujours en cours, actualisez de nouveau une fois que le déploiement a progressé. En cas d’échec de l’installation, l’attribut calculé install_error en précise la cause.

​

Mettre à jour la configuration

​

Configurer l’affinité des exécuteurs

affinity = jsonencode({
  nodeAffinity = {
    preferredDuringSchedulingIgnoredDuringExecution = [{
      weight = 100
      preference = {
        matchExpressions = [{
          key      = "example.com/capacity-class"
          operator = "In"
          values   = ["on-demand"]
        }]
      }
    }]
  }
})

​

Importer un exécuteur existant

terraform init
terraform import coreweave_sandbox_managed_runner.runner '[RUNNER-ID]'
terraform plan

​

Supprimer un exécuteur

​

Voir aussi

• Référence de la ressource d’exécuteur géré.
• Déployer et gérer un exécuteur.
• Configurer une politique de sandbox.